/*
Günlük Burç Yorumcusu v3.0(YENI)

Yazan : YaGMuR_PreNSi

Özelliklerini incelemek için "Beni oku.txt" dosyasını okuyun.

wWw.AnlaSevgimi.Com adresine sonsuz teşekkürler...
*/
dialog astro {
  title "Günlük Burç Yorumcusu v3.0"
  size -1 -1 136 89
  option dbu
  icon $adicon, 0
  text "Bir burç seçiniz:", 1, 4 7 37 8
  combo 2, 43 4 60 103, size drop
  box "", 3, 1 -2 134 20
  button "Oku", 4, 105 4 26 11, disable
  edit "", 5, 1 28 134 46, read multi vsbar
  button "Kapat", 7, 50 76 40 12, flat cancel
  text "", 8, 2 20 133 8
  button "Diğer Seçenekler", 6, 1 76 47 12, disable flat
  link "Muneccim.com'a teşekkürler...", 9, 93 75 40 13
}
dialog burc_opt {
  title "Seçenekler"
  size -1 -1 107 111
  option dbu
  icon $adicon, 0
  button "Burcun Özellikleri", 2, 1 12 48 12
  text "Aşağıdaki Seçeneklerden Birini Seçin:", 1, 6 0 93 8
  box "", 3, -2 5 139 5
  button "Bugünkü Durumunuz", 4, 51 12 54 12
  button "Uyumluluk Analizi", 5, 1 27 48 12
  button "Adınızın baş harfine göre aşk durumunuz", 6, 1 41 104 12
  button "Yükselen burc öğren", 7, 51 27 54 12
  button "Ünlülerin Burçları", 8, 1 55 48 12
  button "Kapat", 9, 1 97 104 12, cancel
  button "Kimlerle anlaşabilirsin", 10, 51 55 54 12
  button "Burçlar ve sağlık", 11, 1 69 48 12
  button "Burçlar ve Arkadaşlık", 12, 51 69 54 12
  button "Yıldızınızı öğrenin", 13, 1 83 48 12
  button "Çin Burcunuz ve Öz.", 14, 51 83 54 12
}

dialog harf_ask {
  title "Baş Harfe Göre Aşk Durumu"
  size -1 -1 91 69
  option dbu
  icon $adicon, 0
  text "İsminizin baş harfini girin:", 1, 1 3 58 8
  box "", 2, -2 9 125 4
  edit "", 3, 59 1 12 10, limit 1
  button "Bak", 4, 72 1 17 10, disable
  edit "İsminizin baş harfini girerken Türkçe karakter(harf) kullanmayın.", 5, 1 15 89 39, read multi vsbar
  button "Kapat", 6, 1 56 89 12, flat cancel
}
dialog yukselen {
  title "Yükselen Burç Öğrenme"
  size -1 -1 94 77
  option dbu
  icon $adicon, 0
  box "", 1, 1 -1 91 76
  text "Hangi tarih aralığında doğdunuz:", 2, 4 5 80  8
  combo 3, 4 14 85 100, size drop
  text "Hangi zaman diliminde doğduğunuz:", 4, 4 27 85 8
  combo 5, 4 36 85 100, disable size drop
  button "Öğren", 6, 4 61 37 12, disable
  button "Kapat", 7, 52 61 37 12, cancel
  edit "Yükselen Burc Öğrenme", 8, 4 49 85 10, read
}
dialog ünlüler {
  title "Bazı Ünlülerin Burçları"
  size -1 -1 110 91
  option dbu
  icon $adicon, 0
  box "", 1, 1 -1 108 22
  text "Bir Burç Seçin:", 2, 3 9 35 8
  combo 3, 39 6 49 100, size drop
  button "Bak", 4, 90 6 16 11, disable
  text "Ünlüler:", 5, 2 23 18 8
  edit "", 6, 1 31 107 46, read multi vsbar
  button "Kapat", 7, 2 78 107 12, flat cancel
}

dialog uyum {
  title "UYUMLULUK ANALIZI"
  size -1 -1 136 146
  option dbu
  icon $adicon, 0
  box "", 1, 1 -1 133 36
  text "KADIN", 2, 4 9 17 8
  combo 3, 22 6 40 100, size drop
  text "ERKEK", 4, 64 9 18 8
  combo 5, 83 6 44 100, disable size drop
  button "Uyumluluğu Göster", 6, 4 20 51 12, disable
  button "Yeni Seçim", 7, 90 20 41 12, disable
  box "", 8, 1 37 133 36
  combo 9, 22 44 40 100, size drop
  text "ERKEK", 10, 3 47 18 8
  text "KADIN", 11, 65 47 17 8
  combo 12, 83 44 44 100, disable size drop
  button "Yeni Seçim", 13, 90 58 41 12, disable
  button "Uyumluluğu Göster", 14, 4 58 51 12, disable
  text "", 15, 1 75 134 8
  edit "", 16, 1 83 134 62, read multi vsbar
  button "Button", 17, 60 47 37 12, hide cancel
}
dialog horin {
  title "Burç Özellikleri"
  size -1 -1 142 87
  option dbu
  icon $adicon, 0
  text "", 2, 1 1 100 7
  edit "", 3, 1 8 140 65, read multi vsbar
  button "Kapat", 4, 100 74 41 12, flat cancel
  button "Oku", 1, 61 74 37 12, flat
}
dialog anlasma {
  title "Kimlerle Anlaşabilirsiniz"
  size -1 -1 109 107
  option dbu
  icon $adicon, 0
  box "", 1, 1 -1 106 30
  text "Burcunuzu Seçin:", 2, 4 5 42 8
  combo 3, 4 14 60 100, size drop
  button "Öğren", 4, 66 14 37 11, disable
  text "Anlaşabileceğiniz Burçlar:", 5, 2 31 60 8
  edit "", 6, 2 39 104 53, read multi
  button "TAMAM/KAPAT", 7, 2 94 104 12, flat cancel
}
dialog burc_saglik {
  title "Burçlar ve Sağlık"
  size -1 -1 109 107
  option dbu
  icon $adicon, 0
  box "", 1, 1 -1 106 30
  text "Burcunuzu Seçin:", 2, 4 5 42 8
  combo 3, 4 14 60 100, size drop
  button "Öğren", 4, 66 14 37 11, disable
  text "Açıklama:", 5, 2 31 23 8
  edit "", 6, 2 39 104 53, read multi vsbar
  button "TAMAM/KAPAT", 7, 2 94 104 12, flat cancel
}
dialog burc_arkadas {
  title "Burçlar ve Arkadaşlık"
  size -1 -1 109 107
  option dbu
  icon $adicon, 0
  box "", 1, 1 -1 106 30
  text "Bir Burç Seçin:", 2, 4 5 42 8
  combo 3, 4 14 60 100, size drop
  button "Öğren", 4, 66 14 37 11, disable
  text "Açıklama:", 5, 2 31 23 8
  edit "", 6, 2 39 104 53, read multi vsbar
  button "TAMAM/KAPAT", 7, 2 94 104 12, flat cancel
}
dialog cburc {
  title "Çin Burcunuz ve Özellikleriniz"
  size -1 -1 132 129
  option dbu
  icon $adicon, 0
  box "", 1, 2 0 128 114
  text "Çin Burcunuzu Seçin:", 2, 6 9 50 8
  combo 3, 58 7 41 100, size drop
  text "Özellikleri:", 4, 6 21 31 8
  edit "", 5, 6 29 122 47, read multi vsbar
  link "Çin Burcunuzu Bilmiyorsanız burdan öğrenebilirsiniz.", 6, 5 77 123 9
  text "Doğum Yılınızı Girin:", 7, 6 90 46 8
  edit "", 8, 53 88 33 10, limit 4
  button "Öğren", 9, 87 88 37 10, disable
  link "Çin Burcunuz:", 10, 6 103 33 8
  text "?", 11, 41 103 85 8
  button "Tamam/Kapat", 12, 3 116 126 11, cancel
  button "Özellikleri", 13, 101 7 26 11, disable
}
dialog yıldız {
  title "Yıldızınızı Öğrenin"
  size -1 -1 137 93
  option dbu
  icon $adicon, 0
  text "Burçlar ve Yıldızları:", 1, 2 2 46 8
  edit "", 2, 1 11 135 67, read multi vsbar
  button "TAMAM/KAPAT", 3, 1 80 135 12, flat cancel
}
alias -l cburc if (!$dialog(cburc)) dialog -m cburc cburc 
alias -l cburcf return $shortfn($scriptdircburc.txt)
alias -l basharf return $shortfn($scriptdirbasharf.txt)
alias -l burc->aktif { if ($did(3).seltext != $null) did -e $dname 4 }
alias -l yıldızlar return $shortfn($scriptdiryıldızlar.txt)
alias -l hordlg {
  if (($2 == -d) && (!$dialog($1))) dialog -mdo $1 $1
  if (!$dialog($1)) dialog -m $1 $1
}
alias yorumcu hordlg astro
alias -l blen { if ($len($did($1).seltext) > 0) did -e $dname $2 }
alias -l burc_ozellik {
  set %horid /karakter/goster.asp?burc= $+ %hrsel $+ &B1=burc+karakteri
  sockclose boz
  sockopen boz muneccim.com 80
}
alias -l burc->yaz {
  did -a $1 $2 Koç
  did -a $1 $2 Boğa
  did -a $1 $2 İkizler
  did -a $1 $2 Yengeç
  did -a $1 $2 Aslan
  did -a $1 $2 Başak
  did -a $1 $2 Terazi
  did -a $1 $2 Akrep
  did -a $1 $2 Yay
  did -a $1 $2 Oğlak
  did -a $1 $2 Kova
  did -a $1 $2 Balık
}
alias -l uyumluluk {
  set %htoh $+($1,=,$2,&,$3,=,$4,&,submit=uyumluluğu göster)
  set %yer $5
  did -ra uyum 16 Bekleyin...
  if ($sock(uyum)) sockclose uyum | sockopen uyum muneccim.com 80
}
on *:sockopen:uyum: {
  if ($sockerr) echo -a 4Bağlantı Yok!
  else {
    sockwrite -n uyum POST %yer HTTP/1.1
    sockwrite -n uyum Content-Type: application/x-www-form-urlencoded; charset="utf-8"
    sockwrite -n uyum Content-Length: $calc($len(%htoh) + 1)
    sockwrite -n uyum Host: muneccim.com
    sockwrite -n uyum 
    sockwrite -n uyum %htoh
  }
}
on *:sockread:uyum: {
  sockread %uyum
  if (width="450"> isin %uyum) { if (!$dialog(uyum) == $null) did -r uyum 16 }
  if (face="MS Serif"> isin %uyum) { if (!$dialog(uyum) == $null) did -a uyum 16 $remove($gettok(%uyum,5-,32),<br>,</big>,</font>,</td>,</p>) }
}
on *:sockopen:boz: {
  if ($sockerr) echo -a Hata!
  else {
    if (!$dialog(horin) == $null) did -a horin 3 Bekleyin...
    sockwrite -n boz GET %horid HTTP/1.1
    sockwrite -n boz Host: muneccim.com
    sockwrite -n boz $clrf
  }
}
on *:sockread:boz: {
  sockread %bozy
  if (width="450"> isin %bozy) { if (!$dialog(horin) == $null) { did -r horin 3 } }
  if (face="Arial isin %bozy) { 
    set %ozellik $remove($gettok(%bozy,4-,32),<,>,/,br,font,strong,Narrow",big,$chr(9)) 
    write boze.txt %ozellik
  }
  if (arzunuz isin %bozy) { write boze.txt --------------------------------------------------------- }
  if (</body> isin %bozy) { loadbuf -o horin 3 $shortfn(boze.txt) | .remove $shortfn(boze.txt) | unset %ozellik %bozy | sockclose boz }
}
on *:dialog:astro:init:*: {
  burc->yaz $dname 2
  tarih_algıla
}
alias -l adicon return $shortfn($scriptdiryorumcu.ico)
alias -l yorum_algılamayı_başlat {
  unset %hcomt
  sockclose astro
  sockopen astro muneccim.com 80
}
alias -l grafik.ciz {
  if (!$window(@durum) == $null) {
    %gx = $calc(%gx + 40)
    if (%gx == 40) { set %gclr $rgb(255,0,0) | set %ney Para }
    if (%gx == 80) { set %gclr $rgb(255,0,255) | set %ney Aşk }
    if (%gx == 120) { set %gclr $rgb(0,0,128) | set %ney İş }
    if (%gx == 160) { set %gclr $rgb(0,128,0) | set %ney Sağlık }
    drawrect -rf @durum %gclr 1 %gx $calc((100 - $1) + 50) 33 $1
    drawtext -r @durum $rgb(0,0,255) Tahoma 11 %gx $calc((100 - $1) + 35) $+(%,$1)
    if ($len(%ney) > 2) drawtext -r @durum $rgb(0,0,255) Tahoma 11 $calc(%gx + 4) 153 %ney 
    else drawtext -r @durum $rgb(0,0,255) Tahoma 11 $calc(%gx + 10) 153 %ney
  }
}
alias -l today->state {
  if (!$dialog(astro)) return $input(Günlük Burç Yorumcusu Ana Dialog'u Açık değil!!,oh,Hata)
  elseif (!$did(astro,2).sel) return $input(Bir burç seçmediniz...!,oh,Hata)
  else {
    if (!$window(@Durum)) {
      window -pkh[0] +t @Durum $calc($dialog(astro).x + 285) $calc($dialog(astro).y - 70) 300 240 | window -a @durum | window @durum iconfile $adicon 
    }
    clear @durum | drawrect -rf @durum $rgb(233,233,233) 1 0 0 300 240 | drawtext -or @durum $rgb(0,0,0) Tahoma 20 20 20 Bir sn bakıyorum...
    if ($sock(tst)) sockclose tst
    sockopen tst muneccim.com 80
    did -b astro 2,9 | set %gx 0
  }
}
alias -l yukselen->ogren {
  did -ra yukselen 8 Bekleyin...
  set %yukselen $+(location=,$did(3).sel,&,count=,$calc($did(5).sel - 1))
  if ($sock(yukselen)) sockclose yukselen
  sockopen yukselen www.muneccim.com 80
}
on *:sockopen:yukselen: {
  if ($sockerr) echo -a Bağlantı Yok!
  else {
    sockwrite -n yukselen POST /yukselen_burc/yukselen_burc_engine.asp HTTP/1.1
    sockwrite -n yukselen Content-Type: application/x-www-form-urlencoded; charset="utf-8"
    sockwrite -n yukselen Content-Length: $calc($len(%yukselen) + 1)
    sockwrite -n yukselen Host: www.muneccim.com
    sockwrite -n yukselen
    sockwrite -n yukselen %yukselen
  }
}
on *:sockread:yukselen: {
  sockread %yuksel 
  if (*Yükselen burcunuz* iswm %yuksel) { if ($sock(yukselen2)) sockclose yukselen2 | sockrename yukselen yukselen2 } 
}
on *:sockread:yukselen2: {
  sockread %yuksel2
  if (!$dialog(yukselen) == $null) did -ra yukselen 8 Yükselen Burcunuz: $remove(%yuksel2,<,>,big,br)
  sockclose yukselen2
}
on *:sockopen:tst: {
  if ($sockerr) echo -a Bağlantı Yok!
  else {
    sockwrite -n tst GET $+(/pais/goster.asp?burc=,%hrsel,&B1=OK) HTTP/1.1
    sockwrite -n tst Host: muneccim.com
    sockwrite -n tst $crlf
  }
}
on *:sockread:tst: {
  sockread %tst
  if (durumunuz isin %tst) { 
    if (!$window(@durum) == $null) { 
      drawrect -rf @durum $rgb(233,233,233) 1 0 0 300 240 
      drawrect -r @durum $rgb(0,128,0) 1 40 30 160 1
      drawrect -r @durum $rgb(0,128,0) 1 40 170 160 1
      drawtext -or @durum $rgb(0,64,128) Tahoma 11 40 15 $did(astro,2).seltext Burcu 
      drawtext -or @durum $rgb(0,128,0) Tahoma 11 40 190 Fala inanmayın falsız da kalmayın (;
    } 
  }
  if (width="33" isin $gettok(%tst,1-,32)) grafik.ciz $remove($gettok(%tst,2,32),height=,",>)
  if (Falınız isin %tst) { sockclose tst | if (!$dialog(astro) == $null) did -e astro 2,9 }
}
alias -l tarih_algıla {
  set %mm $asctime(mm)
  if (%mm == 01) { set %ay Ocak } | elseif (%mm == 02) { set %ay Şubat } | elseif (%mm == 03) { set %ay Mart } | elseif (%mm == 04) { set %ay Nisan }
  elseif (%mm == 05) { set %ay Mayıs } | elseif (%mm == 06) { set %ay Haziran } | elseif (%mm == 07) { set %ay Temmuz } | elseif (%mm == 08) { set %ay Ağustos }
  elseif (%mm == 09) { set %ay Eylül } | elseif (%mm == 10) { set %ay Ekim } | elseif (%mm == 11) { set %ay Kasım } | elseif (%mm == 12) { set %ay Aralık }
}
on *:sockopen:astro: {
  if ($sockerr) { sockclose astro | did -ra astro 5 Internet bağlantısı bulunamadı... }
  else { 
    did -ra astro 5 Yorum bulunuyor.Lütfen bekleyiniz...
    sockwrite -n astro GET /gunluk_fal/bugun.asp?burc= $+ %hrsel HTTP/1.1
    sockwrite -n astro Host:muneccim.com
    sockwrite -n astro $crlf
  }
}
on *:sockread:astro: {
  if ($sockerr) { sockclose astro | did -ra astro 5 Internet bağlantısı bulunamadı... }
  else {
    sockread %hcomt
    if (face="Arial Narrow" isin %hcomt) { 
      set %rmv1 $remove(%hcomt,<p><font color="#000000" face="Arial Narrow"><strong><big>)
      set %rmv2 $remove(%rmv1,$right(%rmv1,27))
      did -ra astro 5 %rmv2
      if (%hrsel == 1) did -ra astro 8 21 Mart - 20 Nisan 
      if (%hrsel == 2) did -ra astro 8 21 Nisan - 21 Mayıs 
      if (%hrsel == 3) did -ra astro 8 22 Mayıs - 21 Haziran 
      if (%hrsel == 4) did -ra astro 8 22 Haziran - 23 Temmuz 
      if (%hrsel == 5) did -ra astro 8 24 Temmuz - 23 Ağustos 
      if (%hrsel == 6)  did -ra astro 8 24 Ağustos - 23 Eylül 
      if (%hrsel == 7)  did -ra astro 8 24 Eylül - 22 Ekim 
      if (%hrsel == 8)  did -ra astro 8 23 Ekim - 22 Kasım
      if (%hrsel == 9)  did -ra astro 8 23 Kasım - 22 Aralık 
      if (%hrsel == 10) did -ra astro 8 23 Aralık - 20 Ocak 
      if (%hrsel == 11) did -ra astro 8 21 Ocak - 19 Şubat 
      if (%hrsel == 12) did -ra astro 8 20 Şubat - 20 Mart 
      did -a astro 8 $did(astro,8).text $+ $chr(32) $+ (Bugün: $+ $chr(32) $+ $asctime(dd) $+ $chr(32) $+ %ay $+ $chr(32) $+ $asctime(yyyy) $+ )
      unset %rmv1 %rmv2 %hcomt
      sockclose astro
    }
  }
}
on *:dialog:astro:sclick:*: {
  if ($did == 2) { if ($len($did(2)) > 0) { did -e $dname 4,6 | set %hrsel $did(2).sel | if (!$dialog(horin) == $null) did -ra horin 2 $did(2).seltext Burcunun Özellikleri: } }
  if ($did == 4) yorum_algılamayı_başlat
  if ($did == 6) hordlg burc_opt
}
on *:dialog:burc_opt:sclick:*: {
  if ($did == 2) { 
    if (!$dialog(astro)) return $input(Günlük Burç Yorumcusu Ana Dialog'u Açık Değil!,oh,Hata)
    elseif (!$did(astro,2).sel) return $input(Bir burç seçmediniz,oh,Hata) 
    else hordlg horin
  }
  if ($did == 4) today->state
  if ($did == 5) hordlg uyum
  if ($did == 7) hordlg yukselen
  if ($did == 6) hordlg harf_ask
  if ($did == 8) hordlg ünlüler
  if ($did == 13) hordlg yıldız
  if ($did == 12) hordlg burc_arkadas
  if ($did == 11) hordlg burc_saglik
  if ($did == 10) hordlg anlasma
  if ($did == 14) cburc
}
alias -l burc->arkadas {
  set %ark $+(/arkadas/goster.asp?burc=,$did(3).sel,&B1=Göster)
  did -ra $dname 6 Bekleyin...
  if ($sock(arkadas)) sockclose arkadas
  sockopen arkadas www.muneccim.com 80
}
alias -l burc->saglik {
  set %sagl $+(/saglik/goster.asp?burc=,$did(3).sel,&B1=Göster)
  did -ra $dname 6 Bekleyin...
  if ($sock(saglik)) sockclose saglik
  sockopen saglik www.muneccim.com 80
}
alias -l burc->anlasma {
  set %anlas $+(/kimlerle_anlasabilir/goster.asp?burc=,$did(3).sel,&B1=kimlerle+anlaşabilir)
  did -ra $dname 6 Bekleyin...
  if ($sock(anlasma)) sockclose anlasma
  sockopen anlasma www.muneccim.com 80
}
on *:sockopen:anlasma: {
  if ($sockerr) { echo -a Bağlantı Yok! | return }
  else {
    sockwrite -n anlasma GET %anlas HTTP/1.1
    sockwrite -n anlasma Host: www.muneccim.com
    sockwrite -n anlasma $crlf
  }
}
on *:sockread:anlasma: {
  sockread %anlasma 
  if (width="450"> isin %anlasma) { if (!$dialog(anlasma) == $null) did -r anlasma 6 }
  if (color="#000000" isin %anlasma) {
    if (!$dialog(anlasma) == $null) {
      if (Arası isin %anlasma) did -a anlasma 6 $remove($gettok(%anlasma,-1,34),<,>,/,strong,font,br,big) 
      else did -a anlasma 6 $+($str($crlf,2),$remove($gettok(%anlasma,-1,34),<,>,/,strong,font,br,big))
    }
  }
  if (</html> isin %anlasma) sockclose anlasma
}
on *:sockopen:arkadas: {
  if ($sockerr) { echo -a Bağlantı Yok! | return }
  else {
    sockwrite -n arkadas GET %ark HTTP/1.1
    sockwrite -n arkadas Host: www.muneccim.com
    sockwrite -n arkadas $crlf
  }
}
on *:sockread:arkadas: {
  sockread %arkadas
  if (width="450"> isin %arkadas) { if (!$dialog(burc_arkadas) == $null) did -r burc_arkadas 6 }
  if (color="#000000" isin %arkadas) { 
    if (!$dialog(burc_arkadas) == $null) {
      if (*arkadaş olarak* iswm %arkadas) did -a burc_arkadas 6 $remove($gettok(%arkadas,-1,34),<,>,/,strong,font,br,big) 
      else did -a burc_arkadas 6 $+($crlf,$remove($gettok(%arkadas,-1,34),<,>,/,strong,font,br,big))
    }
  }
  if (</html> isin %arkadas) sockclose arkadas
}
on *:sockopen:saglik: {
  if ($sockerr) { echo -a Bağlantı Yok! | return }
  else {
    sockwrite -n saglik GET %sagl HTTP/1.1
    sockwrite -n saglik Host: www.muneccim.com
    sockwrite -n saglik $crlf
  }
}
on *:sockread:saglik: {
  sockread %saglik
  if (width="450"> isin %saglik) { if (!$dialog(burc_saglik) == $null) did -r burc_saglik 6 }
  if (color="#000000" isin %saglik) { 
    if (!$dialog(burc_saglik) == $null) {
      if (*burcu ve sağlık* iswm %saglik) did -a burc_saglik 6 $remove($gettok(%saglik,-1,34),<,>,/,strong,font,br,big) 
      else did -a burc_saglik 6 $+($crlf,$remove($gettok(%saglik,-1,34),<,>,/,strong,font,br,big))
    }
  }
  if (</html> isin %saglik) sockclose saglik
}
on *:dialog:ünlüler:init:*: burc->yaz $dname 3
on *:dialog:burc_arkadas:init:*: burc->yaz $dname 3
on *:dialog:burc_saglik:init:*: burc->yaz $dname 3
on *:dialog:anlasma:init:*: burc->yaz $dname 3
on *:dialog:yıldız:init:*: loadbuf -o $dname 2 $yıldızlar
on *:dialog:anlasma:sclick:*: {
  if ($did == 3) burc->aktif
  if ($did == 4) burc->anlasma
}
on *:dialog:burc_saglik:sclick:*: {
  if ($did == 3) burc->aktif
  if ($did == 4) burc->saglik
}
on *:dialog:burc_arkadas:sclick:*: {
  if ($did == 3) burc->aktif
  if ($did == 4) burc->arkadas
}
on *:dialog:ünlüler:sclick:*: {
  if ($did == 3) { if ($did(3).sel > 0) did -e $dname 4 }
  if ($did == 4) { if ($sock(ünlü)) sockclose ünlü | sockopen ünlü www.muneccim.com 80 | did -ra $dname 6 Bulunuyor.Bekleyin... }
}
on *:sockopen:ünlü: {
  if ($sockerr) echo -a Bağlantı Yok!
  else {
    sockwrite -n ünlü GET $+(/unluler/goster.asp?burc=,$did(ünlüler,3).sel,&B1=,burctaki+ünlüler) HTTP/1.1
    sockwrite -n ünlü Host: www.muneccim.com
    sockwrite -n ünlü $crlf
  }
}
on *:sockread:ünlü: {
  sockread %unlu
  if (width="450"> isin %unlu) { if (!$dialog(ünlüler) == $null) did -r ünlüler 6 }
  if (color="#000000" isin %unlu) { 
    if (!$dialog(ünlüler) == $null) { 
      if (!$did(ünlüler,6)) did -a ünlüler 6 $remove($gettok($gettok(%unlu,4-7,60),1,60),big>)
      else did -a ünlüler 6 $+($crlf,$remove($gettok($gettok(%unlu,4-7,60),1,60),big>))
    }
  }
}
on *:dialog:harf_ask:edit:3: { if ($did(3) != $null) { did -e $dname 4 | if ($did(3) isnum) { did -r $dname 3 | did -b $dname 4 } } | else did -b $dname 4 }  
on *:dialog:harf_ask:sclick:4: {
  did -ra $dname 5 Bulunuyor...
  var %hfid = $lines($basharf)
  while (%hfid) {
    tokenize 43 $read($basharf,%hfid)
    if ($1 == $did(3)) { did -r $dname 5,3 | did -a $dname 5 $2 | did -b $dname 4 | halt } 
    elseif ((%hfid == 1) && ($len($did(5)) == 12)) { did -r $dname 5,3 | did -a $dname 5 Bulunamadı.Türkçe karakter girmiş yada listede olmayan bir harf girmiş olabilirsiniz.Yeniden deneyin. | did -b $dname 4 }
    dec %hfid
  }
}
on *:dialog:yukselen:init:*: {
  did -a yukselen 3 21 Haziran - 7 Temmuz
  did -a yukselen 3 8 Temmuz - 22 Temuz
  did -a yukselen 3 23 Temmuz - 7 Ağustos
  did -a yukselen 3 8 Ağustos - 22 Ağustos
  did -a yukselen 3 23 Ağustos - 7 Eylül
  did -a yukselen 3 8 Eylül- 22 Eylül
  did -a yukselen 3 23 Eylül - 8 Ekim
  did -a yukselen 3 9 Ekim - 22 Ekim
  did -a yukselen 3 23 Ekim - 7 Kasım
  did -a yukselen 3 8 Kasım - 22 Kasım
  did -a yukselen 3 23 Kasım - 7 Aralık
  did -a yukselen 3 8 Aralık - 21 Aralık
  did -a yukselen 3 22 Aralık - 5 Ocak
  did -a yukselen 3 6 Ocak - 19 Ocak
  did -a yukselen 3 20 Ocak - 3 Şubat
  did -a yukselen 3 4 Şubat - 18 Şubat
  did -a yukselen 3 19 Şubat - 5 Mart
  did -a yukselen 3 6 Mart - 20 Mart
  did -a yukselen 3 21 Mart - 4 Nisan
  did -a yukselen 3 5 Nisan - 19 Nisan
  did -a yukselen 3 20 Nisan - 5 Mayıs
  did -a yukselen 3 6 Mayıs - 20 Mayıs
  did -a yukselen 3 21 Mayıs - 5 Haziran
  did -a yukselen 3 6 Haziran - 20 Haziran
  did -a yukselen 5 00:00 - 00:59
  did -a yukselen 5 01:00 - 01:59
  did -a yukselen 5 02:00 - 02:59
  did -a yukselen 5 03:00 - 03:59
  did -a yukselen 5 04:00 - 04:59
  did -a yukselen 5 05:00 - 05:59
  did -a yukselen 5 06:00 - 06:59
  did -a yukselen 5 07:00 - 07:59
  did -a yukselen 5 08:00 - 08:59
  did -a yukselen 5 09:00 - 09:59
  did -a yukselen 5 10:00 - 10:59
  did -a yukselen 5 11:00 - 11:59
  did -a yukselen 5 12:00 - 12:59
  did -a yukselen 5 13:00 - 13:59
  did -a yukselen 5 14:00 - 14:59
  did -a yukselen 5 15:00 - 15:59
  did -a yukselen 5 16:00 - 16:59
  did -a yukselen 5 17:00 - 17:59
  did -a yukselen 5 18:00 - 18:59
  did -a yukselen 5 19:00 - 19:59
  did -a yukselen 5 20:00 - 20:59
  did -a yukselen 5 21:00 - 21:59
  did -a yukselen 5 22:00 - 22:59
  did -a yukselen 5 23:00 - 23:59
}
on *:dialog:yukselen:sclick:*: {
  if ($did == 3) { if ($did(3).sel > 0) did -e $dname 5 }
  if ($did == 5) { if ($did(5).sel > 0) did -e $dname 6 }
  if ($did == 6) yukselen->ogren
}
on *:dialog:uyum:init:*: {
  did -a $dname 3,5,9,12 Koc
  did -a $dname 3,5,9,12 Boga
  did -a $dname 3,5,9,12 Ikizler
  did -a $dname 3,5,9,12 Yengec
  did -a $dname 3,5,9,12 Aslan
  did -a $dname 3,5,9,12 Basak
  did -a $dname 3,5,9,12 Terazi
  did -a $dname 3,5,9,12 Akrep
  did -a $dname 3,5,9,12 Yay
  did -a $dname 3,5,9,12 Oglak
  did -a $dname 3,5,9,12 Kova
  did -a $dname 3,5,9,12 Balik
}
on *:dialog:uyum:sclick:*: {
  if ($did == 3) blen 3 5
  if ($did == 5) blen 5 6
  if ($did == 9) blen 9 12
  if ($did == 12) blen 12 14
  if ($did == 6) { uyumluluk Kadin $did(3).seltext Erkek $did(5).seltext /uyumluluk_goster/uyumluluk_goster.asp | did -e $dname 7 | did -ra $dname 15 $did(3).seltext Kadını ile $did(5).seltext Erkeği arasındaki uyum: }
  if ($did == 14) { uyumluluk Erkek $did(9).seltext Kadin $did(12).seltext /uyumluluk_goster/uyumluluk_goster2.asp | did -e $dname 13 | did -ra $dname 15 $did(9).seltext Erkeği ile $did(12).seltext Kadını arasındaki uyum: }
  if ($did == 7) { did -u $dname 3,5 | did -b $dname 6 | did -r $dname 15,16 }
  if ($did == 13) { did -u $dname 9,12 | did -b $dname 14 | did -r $dname 15,16 }
}
on *:dialog:horin:init:*: did -a $dname 2 $did(astro,2).seltext Burcunun Özellikleri:
on *:dialog:horin:sclick:1: { 
  if (!$dialog(astro)) return $input(Günlük Burç Yorumcusu Ana Dialog'u Açık Değil!,oh,Hata)
  elseif (!$did(astro,2).sel) return $input(Birç burç seçmediniz,oh,Hata)
  else {
    did -r $dname 3 | burc_ozellik | write $shortfn(boze.txt) 
  }
}
alias -l cin->hesapla {
  var %x = $calc((1997 - $1) % 12)
  if ((%x == 1) || (%x == -11)) var %cburc = Maymun
  if ((%x == 11) || (%x == -1)) var %cburc = Kaplan
  if ((%x == 10) || (%x == -2)) var %cburc = Tavşan
  if ((%x == 9) || (%x == -3)) var %cburc = Ejderha
  if ((%x == 8) || (%x == -4)) var %cburc = Yılan
  if ((%x == 7) || (%x == -5)) var %cburc = At
  if ((%x == 6) || (%x == -6)) var %cburc = Koyun
  if ((%x == 5) || (%x == -7)) var %cburc = Horoz
  if ((%x == 3) || (%x == -9)) var %cburc = Köpek
  if ((%x == 2) || (%x == -10)) var %cburc = Domuz
  if (%x == 0) did -ra cburc 11 Bulunamadı...
  else did -ra cburc 11 %cburc
}
on *:dialog:cburc:init:*: {
  var %d = did -a $dname 3
  %d Fare | %d Kaplan | %d Ejderha | %d Yılan | %d At | %d Keçi | %d Maymun | %d Öküz | %d Köpek | %d Domuz | %d Horoz | %d Kedi
}
on *:dialog:cburc:edit:8: {
  if ($did(8)) {
    if ($did(8) !isnum) { did -r $dname 8 | did -b $dname 9 }
    did -e $dname 9
  }
  else did -b $dname 9
}
on *:dialog:cburc:sclick:*: {
  if $did == 3 { if ($did(3).seltext) did -e $dname 13 }
  if $did == 13 did -ra $dname 5 $read($cburcf,$did(3).sel)
  if $did == 9 cin->hesapla $did(8)
}
on *:load: {
  if ($isfile($adicon) == $false) { echo Addon yüklenemiyor.4"yorumcu.ico" adlı ikon dosyasını "4 $+ $scriptdir "adlı yere kopyalayın ve tekrar addonu yükleyin. | .unload -rs $shortfn($script) }
  elseif ($isfile($basharf) == $false) { echo Addon yüklenemiyor.4"basharf.txt" adlı dosyayı 4" $+ $scriptdir "adlı yere kopyalayın ve tekrar addonu yükleyin. | .unload -rs $shortfn($script) }
  elseif ($isfile($yıldızlar) == $false) { echo Addon yüklenemiyor.4"yıldızlar.txt" adlı dosyayı 4" $+ $scriptdir "adlı yere kopyalayın ve tekrar addonu yükleyin. | .unload -rs $shortfn($script) }  
  elseif ($isfile($cburcf) == $false) { echo Addon yüklenemiyor.4"cburc.txt" adlı dosyayı 4" $+ $scriptdir "adlı yere kopyalayın ve tekrar addonu yükleyin. | .unload -rs $shortfn($script) }    
  else {  
    echo 4Günlük Burç Yorumcusu 7v3.0 addonu yüklendi.
    echo Açmak için 4/yorumcu yazın.Menubar veya status'den de açabilirsiniz...
    echo 4www.muneccim.com adresine sonsuz teşekkürler...
  }
}
on *:unload: {
  unset %mm %ay %hrsel %horid %tst %gx %gclr %ney %uyum %htoh %yer %bozy %ozellik %hcomt %yukselen %yuksel %yuksel2 %unlu %bash %saglik %arkadas %anlasma %sagl %anlas %ark
  if ($isfile($basharf) == $true) .remove $basharf
  echo 4Günlük Burç Yorumcusu  $+ $color(normal text) $+ addonu kaldırıldı.
}
menu menubar,status {
  Günlük Burç Yorumcusu
  .Bugünkü burç yorumunuz : yorumcu
  .Uyumluluk Analizi : hordlg uyum
  .Yükselen Burç öğrenme : hordlg yukselen
  .Baş harfe göre aşk durumu : hordlg harf_ask
  .Bazı ünlü kişilerin Burçları : hordlg ünlüler
  .Kimlerle anlaşabilirsin : hordlg anlasma
  .Burçlar ve sağlık : hordlg burc_saglik
  .Burçlar ve arkadaşlık : hordlg burc_arkadas
  .Yıldızını öğrenin : hordlg yıldız
  .Çin burcunuz ve özellikleri: cburc
  .-
  .Addonu Kaldır : .unload -rs $shortfn($script)
}
