;#################################
; Mesaj Uyarıcısı (MUY) ---> Güncellenmiş version

; Version : 0.2

; Yazan : SeRDaR406

; mIRC aktif değil iken özelinize mesaj geldiğinde

; sizi uyarır.Web'de sörf yaparken ihtiyacınız olacaktır.

; Eklenti Yapılmıştır.Yapılan eklenti: Kanalda birisi size

; seslendiğinde sizi uyarma olayı eklenmiştir.

;Uyarıcıs pencerelerine, uyarıcıları açma kapatma özelliği

;eklenmiştir.
;#################################
;KOD BAŞLANGICI
;###############
;  Aliaslar
;###############
alias -l muydlg {
  if (!$dialog($1)) dialog -m $1 $1 
  muy_pre
}
alias -l muy_style { if (!$dialog(muystyle)) dialog -m muystyle muystyle }
alias -l muyw return @MUY(Önizleme)
alias -l dwrc { 
  if ($7 == -f) drawrect -rf $1 $2 1 $3 $4 $5 $6
  else drawrect -r $1 $2 1 $3 $4 $5 $6
}
alias -l dwtxt { 
  if ($1 == -k) drawtext -or $2 $3 Tahoma 10 $4 $5 $6-
  elseif ($1 == -kg) drawtext -orc $2 $3 Tahoma 10 $4 $5 $6 $7 $8-
  elseif ($1 == -g) drawtext -rc $2 $3 Tahoma 10 $4 $5 $6 $7 $8- 
  else drawtext -r $1 $2 Tahoma 10 $3 $4 $5- 
}
alias -l temargb {
  var %tmv = 1
  if ($3 == -m) { set %mnx 0 | set %mny 0 }
  elseif ($3 == $null) { set %mnx 20 | set %mny 17 }
  while (%tmv <= 170) {
    if ($1 == -g) { dwrc $2 $rgb($calc(%tmv + 85),$calc(%tmv + 85),$calc(%tmv + 85))  %mnx %mny %tmv 20 }
    if ($1 == -k) { dwrc $2 $rgb($calc(%tmv + 85),20,83) %mnx %mny %tmv 20 }
    if ($1 == -s) { dwrc $2 $rgb($calc(%tmv + 85),$calc(%tmv + 85),0) %mnx %mny %tmv 20 }
    if ($1 == -y) { dwrc $2 $rgb(0,$calc(%tmv + 85),0) %mnx %mny %tmv 20 }
    if ($1 == -b) { dwrc $2 $rgb(30,30,$calc(%tmv + 85)) %mnx %mny %tmv 20 }
    if ($1 == -p) { dwrc $2 $rgb($calc(%tmv + 85),0,$calc(%tmv + 85)) %mnx %mny %tmv 20 }
    if ($1 == -f) { dwrc $2 $rgb($calc(%tmv + 85),125,%tmv) %mnx %mny %tmv 20 }
    if ($1 == -f2) { dwrc $2 $rgb(128,128,$calc(%tmv + 85)) %mnx %mny %tmv 20 }
    if ($1 == -f3) { dwrc $2 $rgb(124,$calc(%tmv + 5),38) %mnx %mny %tmv 20 }
    if ($1 == -f4) {  dwrc $2 $rgb(211,%tmv,11) %mnx %mny %tmv 20 }
    if ($1 == -f5) { dwrc $2 $rgb(%tmv,%tmv,$calc(%tmv + 32)) %mnx %mny %tmv 20 }
    if ($1 == -f6) { dwrc $2 $rgb(%tmv,$calc(%tmv + 17),$calc(%tmv + 48)) %mnx %mny %tmv 20 }
    if ($1 == -f7) { dwrc $2 $rgb(100,$calc(%tmv + 20),$calc(%tmv + 80)) %mnx %mny %tmv 20 }
    if ($1 == -f8) { dwrc $2 $rgb(%tmv,$remove($calc(%tmv - 101),-),%tmv) %mnx %mny %tmv 20 }
    if ($1 == -f9) { dwrc $2 $rgb(%tmv,$calc(%tmv + 37),29) %mnx %mny %tmv 20 }
    if ($1 == -f10) { dwrc $2 $rgb(%tmv,%tmv,20) %mnx %mny %tmv 20 } 
    inc %tmv
  }
}
alias -l tmn { did -a muyd 4 $1- }
alias -l mck { did -c muyd $1 $2 }
alias muy muy_style 
alias -l nmsg { 
  if (!$window($1)) { .timernmsg off }
  if ($2 == -m) { set %mnx::win 45 | set %mny::win 35 }
  elseif (!$2) { set %mnx::win 63 | set %mny::win 53 }
  %mlen = $calc(%mlen + 2)
  if (%mlen == %nmsgl) { dwrc $1 %muybgclr %mnx::win %mny::win %nmsgl 13 -f | set %mlen 0 }
  if ($window($1)) { dwtxt -kg $1 %nmsgclr %mnx::win %mny::win %mlen 13 Yeni mesajınız var... }
}
alias muyw_tools {
  if (%::pnicon == $null) drawpic $muyw 25 40 $shortfn($scriptdirusers.ico)
  else drawpic $muyw 25 40 $shortfn(%::pnicon)
  if (%::titicon == $null) drawpic -s $muyw 23 19 16 16 $shortfn($scriptdirinfo.ico)
  else drawpic -s $muyw 23 19 16 16 $shortfn(%::titicon)
  dwtxt -k $muyw %muytit 43 21  Mesaj Uyarıcısı
  dwtxt -k $muyw %muynick 25 75 Nick:  
  dwtxt $muyw %muymsg 53 75 SeRDaR406
  dwtxt -k $muyw %muynick 25 100 Mesaj:
  dwtxt $muyw %muymsg 60 100 Selamın aleyküm
  set %mlen 0
  set %nmsgl $width(Yeni mesajınız var ...,Tahoma,10,1)
  .timernmsg 0 0 nmsg $muyw
}
alias win::algıla {
  if (!$window($muyw)) { 
  if (($dialog(muyd)) && ($did(muyd,20) == Önizleme $+ $chr(40) $+ Açık $+ $chr(41))) { did -ra muyd 20 Önizleme(Kapalı) | did -e muyd 20 } }
  if (($dialog(muyd)) && (!$window($muyw))) { window -c $muyw | .timerwinsor off }
}
alias muy_pre {
  win::values
  set %mlen 0
  if (!$window($muyw)) { 
    window -ahpdok[0] +tL $muyw $calc($dialog(muyd).x + 290) $calc($dialog(muyd).y + 34)  230 160 
    window -a $muyw  
  }
  if ($window($muyw)) { 
    drawrect -rf $muyw $rgb(255,255,255) 1 0 0 230 160
    dwrc $muyw %muybgclr 20 17 170 100 -f
    if (%mtema == gri) {
      temargb -g $muyw  
    }
    if (%mtema == red) {
      temargb -k $muyw
    }
    if (%mtema == sari) {
      temargb -s $muyw
    }
    if (%mtema == green) {
      temargb -y $muyw
    }
    if (%mtema == blue) {
      temargb -b $muyw
    }
    if (%mtema == pink) {
      temargb -p $muyw
    }
    if (%mtema == farkli) {
      temargb -f $muyw
    }
    if (%mtema == farkli2) {
      temargb -f2 $muyw
    }
    if (%mtema == farkli3) {
      temargb -f3 $muyw
    }
    if (%mtema == farkli4) {
      temargb -f4 $muyw
    }
    if (%mtema == farkli5) {
      temargb -f5 $muyw
    }
    if (%mtema == farkli6) {
      temargb -f6 $muyw
    }
    if (%mtema == farkli7) { 
      temargb -f7 $muyw
    }
    if (%mtema == farkli8) {
      temargb -f8 $muyw
    }
    if (%mtema == farkli9) {
      temargb -f9 $muyw
    }
    if (%mtema == farkli10) {
      temargb -f10 $muyw
    }
    dwrc $muyw 0 20 17 170 100
    dwrc $muyw 0 20 17 170 20
    muyw_tools
  }
}
;########################
;MUY Penceresi Kapat Tuşu çiziliyor...
;########################
alias -l muy::cbutton {
  if (%mtema == gri) { set %b::clr $rgb(128,128,128) | set %btxt::clr $rgb(192,192,192) }
  if (%mtema == red) { set %b::clr $rgb(128,0,0) | set %btxt::clr $rgb(255,0,0) }
  if (%mtema == sari) { set %b::clr $rgb(128,128,0) | set %btxt::clr $rgb(255,255,128) }
  if (%mtema == green) { set %b::clr $rgb(0,128,0) | set %btxt::clr $rgb(128,255,128) }
  if (%mtema == blue) { set %b::clr $rgb(0,0,128) | set %btxt::clr $rgb(81,81,255) }
  if (%mtema == pink) { set %b::clr $rgb(128,0,128) | set %btxt::clr $rgb(255,128,192) }
  if (%mtema == farkli) { set %b::clr $rgb(91,125,6) | set %btxt::clr $rgb(243,219,100) }
  if (%mtema == farkli2) { set %b::clr $rgb(128,128,192) | set %btxt::clr $rgb(255,255,128) }
  if (%mtema == farkli3) { set %b::clr $rgb(124,8,38) | set %btxt::clr $rgb(239,208,91) }
  if (%mtema == farkli4) { set %b::clr $rgb(211,46,11) | set %btxt::clr $rgb(255,255,128) }
  if (%mtema == farkli5) { set %b::clr $rgb(64,64,130) | set %btxt::clr $rgb(192,192,192) }
  if (%mtema == farkli6) { set %b::clr $rgb(85,102,133) | set %btxt::clr $rgb(150,176,207) }
  if (%mtema == farkli7) { set %b::clr $rgb(5,89,146) | set %btxt::clr $rgb(255,255,255) }
  if (%mtema == farkli8) { set %b::clr $rgb(117,0,117) | set %btxt::clr $rgb(255,255,255) }
  if (%mtema == farkli9) { set %b::clr $rgb(45,82,29) | set %btxt::clr $rgb(255,255,255) }
  if (%mtema == farkli10) { set %b::clr $rgb(105,105,20) | set %btxt::clr $rgb(255,255,183) }
  dwrc @muyar %b::clr 155 5 12 12 -f
  dwrc @muyar $rgb(0,0,0) 155 5 12 12
  dwtxt -k @muyar %btxt::clr 158 5 X
}
alias -l up::win {
  if ($window(@muyar)) {
    %wy = $calc(%wy - 8)
    window @muyar %wx %wy 170 100 
    if (%wy == $calc($window(-1).h - 128)) { if ($window(@muyar)) { .timergitgel 1 5 down::win2 } | .timerwinup off }
  }
}
alias -l down::win2 { .timerwindwn 0 0 down::win }
alias -l down::win {
  if ($window(@muyar)) {
    %wy = $calc(%wy + 8)
    window @muyar %wx %wy 170 100 
    if (%wy = $calc($window(-1).h + 128)) { .timerwindwn off | .timernmsg off | window -c @muyar }
  }
}
alias muyar { 
  win::values
  set %mlen 0
  if ((%muy::state == on) && ($window(@muyar))) {
    set %wy $calc($window(-1).h + 128)
    if (%win::pos == right) set %wx $calc($window(-1).w - 180) 
    if (%win::pos == left) set %wx $calc($window(-1).x + 10)
    window -dohpB +Ld @muyar %wx %wy 170 100 
    window @muyar %wx %wy
    dwrc @muyar 0 128 21 $width(Ayarlar,Tahoma,10,1) $height(Ayarlar,Tahoma,10)
    dwrc @muyar %muybgclr 0 0 170 100 -f
    temargb %rgbp @muyar -m
    dwrc @muyar 0 0 0 170 100
    dwrc @muyar 0 0 0 170 20
    if (%::titicon != $null) { drawpic -s @muyar 5 2 16 16 $shortfn(%::titicon) }
    else drawpic -s @muyar 5 3 16 16 $shortfn($scriptdirinfo.ico)
    if (%::pnicon != $null) drawpic @muyar 5 22 $shortfn(%::pnicon)
    else drawpic @muyar 5 22 $shortfn($scriptdirusers.ico)
    dwtxt -k @muyar %muytit 25 4 Mesaj Uyarıcısı
    dwtxt -k @muyar %muynick 5 57 Nick:
    dwtxt -k @muyar %muynick 5 80 Mesaj:
    if ($width($nick,Tahoma,10) <= 119) { 
      dwtxt @muyar %muymsg 33 57 $nick
    }
    else {
      dwtxt -g @muyar %muymsg 33 57 119 13 $nick
      dwtxt @muyar %muymsg $calc(35 + 119) 57 ...
    }
    if ($width($1-,Tahoma,10) <= 115) {
      dwtxt @muyar %muymsg 40 80 $1-
    }
    else {
      dwtxt -g @muyar %muymsg 40 80 115 13 $1-
      dwtxt @muyar %muymsg $calc(42 + 115) 80 ...
    }
    muy::cbutton
    dwtxt -k @muyar $rgb(255,255,255) 128 21 Ayarlar
    dwrc @muyar $rgb(255,255,255) 127 $calc($height(Ayarlar,Tahoma,10) + 20) $width(Ayarlar,Tahoma,10,1) 1
    .timernmsg 0 0 nmsg @muyar -m
    .timerwinup 0 0 up::win
    cbox @muyar 138 4 | cdid -c 1 | cdid -k 1 cdidk2
    if (%::sndf != $null) { .splay $shortfn(%::sndf) }
  }
} 
alias cdidk2 set %muy::state off
alias -l sel_titlebar_icon {
  set %::titicon $sfile($mircdir,Lütfen bir ikon dosyası seçin)
  if ($len(%::titicon) > 0) {
    if ($gettok($nopath(%::titicon),2,46) != ico) { return $input(Hata! $+ $crlf $+ $crlf $+ Seçtiğiniz dosya bir ikon dosyası değil!,ohud,Hata) }
    elseif ($window($muyw)) { 
      set %icon::tmode $true
      did -ra muyd 15 %::titicon | temargb %rgbp $muyw | dwrc $muyw 0 20 17 170 20 | drawpic -s $muyw 23 19 16 16 $shortfn(%::titicon) 
      dwtxt -k $muyw %muytit 41 21 Mesaj Uyarıcısı
    }
  }
}
alias -l sel_panel_icon {
  set %::pnicon $sfile($mircdir,Lütfen bir ikon dosyası seçin)
  if ($len(%::pnicon) > 0) {
    if ($gettok($nopath(%::pnicon),2,46) != ico) { return $input(Hata! $+ $crlf $+ $crlf $+ Seçtiğiniz dosya bir ikon dosyası değil!,ohud,Hata) }
    elseif ($window($muyw)) { 
      set %icon::pmode $true
      did -ra muyd 18 %::pnicon | dwrc $muyw %muybgclr 25 40 33 33 -f | drawpic $muyw 25 40 $shortfn(%::pnicon)
    }
  }
}
alias -l sel_snd_file {
  set %::sndf $sfile($mircdir,Dosya Seç)
  if ($len(%::sndf) > 0) {
    if ($gettok($nopath(%::sndf),2,46) != wav) { return $input(Hata! $+ $crlf $+ $crlf $+ Seçilecek dosyanın uzantısı "wav" olmalıdır.,ohud,Hata) }
    else { did -ra muyd 8 %::sndf | did -e muyd 21 }
  }
}
;##################
;Pencere için değerler
;##################
alias -l win::values {
  if (%mtema == $null) { set %mtema red }
  if (%nmsgclr == $null) { set %nmsgclr $rgb(255,128,0) }
  if (%muytit == $null) { set %muytit $rgb(255,255,255) }
  if (%muynick == $null) { set %muynick %nmsgclr }
  if (%muymsg == $null) { set %muymsg $rgb(255,255,255) }
  if (%mlen == $null) { set %mlen 0 }
  if (%nmsgl == $null) { set %nmsgl $width(Yeni mesajınız var ...,Tahoma,10,1) }
  if (%muybgclr == $null) { set %muybgclr $rgb(64,0,0) }
  if (%rgbp == $null) { set %rgbp -k }
  if (%win::pos == $null) { set %win::pos right }
  if (%muy::state == $null) { set %muy::state on }
}
;##################
;        Ayarlar Dialogu
;##################
dialog muyd {
  title "Mesaj Uyarıcısı(MUY) v0.2 Ayarları"
  size -1 -1 142 198
  option dbu
  icon $mircexe, 0
  box "", 1, 1 -2 140 36
  text "Buradan mesaj uyarıcısı penceresinin renk temasını değiştirebilir ve önizliyebilirsiniz.", 2, 4 4 135 15
  text "Bir renk teması seçiniz:", 3, 4 22 54 8
  combo 4, 59 20 60 104, size drop
  box "", 5, 1 33 140 37
  text "Buradan mesaj uyarıcısı penceresi açıldığı zaman uyarı sesi olarak herhangi bir ses dosyasını atayabilirsiniz.", 6, 4 39 135 15
  text "Dosya seçin:", 7, 4 57 31 8
  edit "", 8, 35 56 60 10, read autohs
  button "Seç", 9, 118 56 21 10
  button "İlk ayarlar geri dön", 10, 1 185 52 12, flat
  button "Kapat", 11, 101 185 39 12, flat cancel
  box "", 12, 1 69 140 50
  text "Buradan mesaj uyarıcısı penceresinin başlık çubuğu(titlebar) ikonunu ve panel ikonunu değiştirebilirsin.", 13, 3 74 139 15
  text "Başlık çubuğu(titlebar) ikonu:", 14, 3 93 70 8
  edit "", 15, 74 91 49 10, read autohs
  button "Seç", 16, 124 91 15 10
  text "Panel ikonu:", 17, 3 108 30 8
  edit "", 18, 34 106 89 10, read autohs
  button "Seç", 19, 124 106 15 10
  button "Önizleme(Açık)", 20, 54 185 45 12, disable flat
  button "Dinle >", 21, 96 56 21 10, disable
  box "", 22, 1 118 140 33
  text "Buradan mesaj uyarıcısı penceresinin ekranın hangi tarafından açılacağını ayarlayabilirsiniz.", 23, 3 124 136 14
  radio "Ekranın sağ tarafından", 24, 3 140 64 10, group
  radio "Ekranın sol tarafından", 25, 71 140 64 10, group
  box "", 26, 1 150 140 33
  text "Buradan mesaj uyarma olayının gerçekleşip gerçekleşmeyeceğini ayarlayabilirsiniz.", 27, 3 155 135 14
  radio "Uyarıcı Açık", 28, 3 171 40 10, group
  radio "Uyarıcı Kapalı", 29, 54 171 43 10, group
}


dialog muystyle {
  title "Mesaj Uyarıcısı [MUY] "
  size -1 -1 107 34
  option dbu
  icon $shortfn($mircexe), 0
  box "", 1, 1 -1 104 33
  text "Kullanmak ve ayarlarını değiştirmek istediğiniz stili seçin:", 3, 4 5 98 15
  radio "Normal stil", 2, 4 21 37 10, flat
  radio "Msn Stili", 4, 47 21 31 10, flat
  button "Button", 5, 43 46 37 12, hide cancel
}

dialog muy_msn {
  title "MesaJ Uyarıcısı(Msn Stili Ayarları)"
  size -1 -1 118 153
  option dbu
  icon $shortfn($mircexe), 0
  box "Ikon ayarları", 1, 1 1 115 50
  text "Başlık çubuğu ikonu:", 2, 4 10 50 8
  edit "", 3, 3 18 93 10, read autohs
  button "Seç", 4, 97 18 16 10
  text "Panel ikonu:", 5, 4 30 30 8
  edit "", 6, 3 38 93 10, read autohs
  button "Seç", 7, 97 38 16 10
  box "Ses ayarı", 8, 1 52 116 32
  text "Uyarı penceresi açıldığı zaman çalacak ses:", 9, 4 61 105 8
  edit "", 10, 3 70 71 10, read autohs
  button "Seç", 11, 75 70 16 10
  button ">", 12, 93 70 16 10, disable
  box "Durum ayarları", 13, 1 86 116 36
  radio "Pencere ekranın sağ köşesinde açılsın", 14, 4 97 100 10, group flat
  radio "Pencere ekranın sol köşesinde açılsın", 15, 4 110 100 10, flat
  button "İlk ayarlara dön", 16, 1 140 41 12
  button "Önizleme(Açık)", 17, 44 140 42 12, disable
  radio "Uyarıcı Açık", 18, 4 125 40 10, group flat
  radio "Uyarıcı Kapalı", 19, 46 125 44 10, flat
  box "", 20, -3 134 124 4
  button "Kapat", 21, 88 140 29 12, cancel
}

;#######################
;Ayalar Dialog Init Olayı
;#######################
on *:dialog:muyd:init:*: {
  if (%mtema == $null) { set %mtema red }
  if (%nmsgclr == $null) { set %nmsgclr $rgb(255,128,0) }
  if (%muytit == $null) { set %muytit $rgb(255,255,255) }
  if (%muynick == $null) { set %muynick %nmsgclr }
  if (%muymsg == $null) { set %muymsg $rgb(255,255,255) }
  if (%mlen == $null) { set %mlen 0 }
  if (%nmsgl == $null) { set %nmsgl $width(Yeni mesajınız var ...,Tahoma,10,1) }
  if (%muybgclr == $null) { set %muybgclr $rgb(64,0,0) }
  if (%rgbp == $null) { set %rgbp -k }
  if (%win::pos == $null) { set %win::pos right }
  if (%muy::state == $null) { set %muy::state on }
  tmn Gri | tmn Kırmızı | tmn Sarı | tmn Yeşil | tmn Mavi | tmn Pembe | tmn Farklı Tema-1 | tmn Farklı Tema-2 | tmn Farklı Tema-3 | tmn Farklı Tema-4
  tmn Farklı Tema-5 | tmn Farklı Tema-6 | tmn Farklı Tema-7 | tmn Farklı Tema-8 | tmn Farklı Tema-9 | tmn Farklı Tema-10
  if (%mtema == gri) { set %tm::id 1 }
  elseif (%mtema == red) { set %tm::id 2 }
  elseif (%mtema == sari) { set %tm::id 3 }
  elseif (%mtema == green) { set %tm::id 4 }
  elseif (%mtema == blue) { set %tm::id 5 }
  elseif (%mtema == pink) { set %tm::id 6 }
  elseif (%mtema == farkli) { set %tm::id 7 }
  elseif (%mtema == farkli2) { set %tm::id 8 }
  elseif (%mtema == farkli3) { set %tm::id 9 }
  elseif (%mtema == farkli4) { set %tm::id 10 }
  elseif (%mtema == farkli5) { set %tm::id 11 }
  elseif (%mtema == farkli6) { set %tm::id 12 }
  elseif (%mtema == farkli7) { set %tm::id 13 }
  elseif (%mtema == farkli8) { set %tm::id 14 }
  elseif (%mtema == farkli9) { set %tm::id 15 }
  elseif (%mtema == farkli10) { set %tm::id 16 }
  mck 4 %tm::id
  if (%win::pos == right) { mck 24 0 }
  if (%win::pos == left) { mck 25 0 }
  if (%muy::state == on) { mck 28 0 }
  if (%muy::state == off) { mck 29 0 }
  if (%icon::tmode == $true) { 
    if ($isfile($shortfn(%::titicon)) == $true) { did -a $dname 15 %::titicon }
  }
  if (%icon::pmode == $true) {
    if ($isfile($shortfn(%::pnicon)) == $true) { did -a $dname 18 %::pnicon }
  }
  if (%::sndf != $null) {
    if ($isfile($shortfn(%::sndf)) == $true) { did -a $dname 8 %::sndf | did -e $dname 21 }
  }
  .timerwinsor 0 0 win::algıla
}

;#######################
;Ayarlar Dialogu Clickleme Olayı
;#######################
on *:dialog:muyd:sclick:*: {
  if ($did == 4) { 
    if ($did(4).sel > 0) { 
      if ($did(4).sel == 1) { 
        set %mtema gri
        set %muybgclr $rgb(107,107,107)
        set %nmsgclr $rgb(192,192,192) | set %muytit $rgb(0,0,0) | set %muynick $rgb(192,192,192) | set %muymsg $rgb(177,177,99)
        set %rgbp -g
      }
      if ($did(4).sel == 2) {
        set %mtema red
        set %muybgclr $rgb(64,0,0)
        set %muytit $rgb(255,255,255)
        set %nmsgclr $rgb(255,128,0) | set %muynick %nmsgclr | set %muymsg $rgb(255,255,255)
        set %rgbp -k
      }
      if ($did(4).sel == 3) {
        set %mtema sari
        set %muytit $rgb(255,255,255)
        set %muybgclr $rgb(128,128,0)
        set %nmsgclr $rgb(255,255,0) | set %muynick %nmsgclr | set %muymsg $rgb(255,255,255)
        set %rgbp -s
      }
      if ($did(4).sel == 4) {
        set %mtema green
        set %muytit $rgb(255,255,255)
        set %muybgclr $rgb(0,128,0)
        set %nmsgclr $rgb(128,255,128) | set %muynick %nmsgclr | set %muymsg $rgb(255,255,255)
        set %rgbp -y
      }
      if ($did(4).sel == 5) {
        set %mtema blue
        set %muytit $rgb(255,255,255)
        set %muybgclr $rgb(0,0,160)
        set %nmsgclr $rgb(157,157,255) | set %muynick %nmsgclr | set %muymsg $rgb(255,255,255)
        set %rgbp -b
      }
      if ($did(4).sel == 6) {
        set %mtema pink
        set %muytit $rgb(255,255,255)
        set %muybgclr $rgb(117,0,117)
        set %nmsgclr $rgb(255,128,255) | set %muynick %nmsgclr | set %muymsg $rgb(255,255,255)
        set %rgbp -p
      }
      if ($did(4).sel == 7) {
        set %mtema farkli
        set %muybgclr $rgb(73,88,14)
        set %muytit $rgb(255,255,255)
        set %nmsgclr $rgb(192,255,62) | set %muynick %nmsgclr | set %muymsg $rgb(255,255,255)
        set %rgbp -f
      }
      if ($did(4).sel == 8) {
        set %mtema farkli2
        set %muybgclr $rgb(70,70,140)
        set %muytit $rgb(255,255,255)
        set %nmsgclr $rgb(140,140,198) | set %muynick %nmsgclr | set %muymsg $rgb(255,255,255)
        set %rgbp -f2
      }
      if ($did(4).sel == 9) {
        set %mtema farkli3
        set %muybgclr $rgb(124,112,38)
        set %muytit $rgb(255,255,255)
        set %nmsgclr $rgb(199,180,71) | set %muynick %nmsgclr | set %muymsg $rgb(255,255,255)
        set %rgbp -f3
      }
      if ($did(4).sel == 10) { 
        set %mtema farkli4 
        set %muybgclr $rgb(211,118,11)
        set %muytit $rgb(255,255,255)
        set %nmsgclr $rgb(255,255,0) | set %muynick %nmsgclr | set %muymsg $rgb(255,255,255)
        set %rgbp -f4
      }
      if ($did(4).sel == 11) {
        set %mtema farkli5
        set %muybgclr $rgb(119,119,151)
        set %muytit $rgb(255,255,255)
        set %nmsgclr $rgb(192,192,192) | set %muynick %nmsgclr | set %muymsg $rgb(255,255,196)
        set %rgbp -f5
      }
      if ($did(4).sel == 12) {
        set %mtema farkli6
        set %muybgclr $rgb(91,108,139)
        set %muytit $rgb(255,255,255)
        set %nmsgclr $rgb(192,192,192) | set %muynick %nmsgclr | set %muymsg $rgb(200,206,217)
        set %rgbp -f6
      }
      if ($did(4).sel == 13) {
        set %mtema farkli7
        set %muytit $rgb(255,255,255)
        set %muybgclr $rgb(100,88,148)
        set %nmsgclr $rgb(192,192,192) | set %muynick %nmsgclr | set %muymsg $rgb(100,189,249)
        set %rgbp -f7
      }
      if ($did(4).sel == 14) {
        set %mtema farkli8
        set %muytit $rgb(255,255,255)
        set %muybgclr $rgb(81,20,81) 
        set %nmsgclr $rgb(255,128,64) | set %muynick %nmsgclr | set %muymsg $rgb(255,64,255)
        set %rgbp -f8
      }
      if ($did(4).sel == 15) {
        set %mtema farkli9
        set %muytit $rgb(255,255,255)
        set %muybgclr $rgb(76,113,29) | set %nmsgclr $rgb(128,255,128) | set %muynick %nmsgclr | set %muymsg $rgb(255,255,255)
        set %rgbp -f9
      }
      if ($did(4).sel == 16) {
        set %mtema farkli10
        set %muytit $rgb(255,255,255)
        set %muybgclr $rgb(105,105,20) | set %nmsgclr $rgb(255,255,0) | set %muynick %nmsgclr | set %muymsg $rgb(255,255,183)
        set %rgbp -f10
      }
      muy_pre
    }
  }
  if ($did == 16) { sel_titlebar_icon }
  if ($did == 19) { sel_panel_icon }
  if ($did == 9) { sel_snd_file }
  if ($did == 24) { set %win::pos right | did -u $dname 25 }
  if ($did == 25) { set %win::pos left | did -u $dname 24 }
  if ($did == 21) { splay %::sndf }
  if ($did == 20) { did -ra $dname 20 Önizleme(Açık) | did -b $dname 20 | muy_pre }
  if ($did == 10) {
    did -u $dname 25,29
    did -b $dname 21
    did -r $dname 8,15,18
    mck 24 0 | mck 4 2 | mck 28 0 
    unset %::sndf %::pnicon %::titicon %win::pos %muy::state %muy::update %mtema %muybgclr %nmsgclr %muytit %muymsg %muynick %rgbp %mlen %nmsgl
    muy_pre
  }
  if ($did == 28) { did -u $dname 29 | set %muy::state on }
  if ($did == 29) { did -u $dname 28 | set %muy::state off }
}
alias -l muy_msn_tools {
  if ($window(@muymsnp)) {
    drawpic @muymsnp 5 5 $shortfn($scriptdirmsn.jpg)
    if (!%mtit::msn) drawpic -s @muymsnp 8 8 16 16 $shortfn($scriptdirinfo.ico)
    else { drawpic -s @muymsnp 8 8 16 16 $shortfn(%mtit::msn) | did -ra muy_msn 3 %mtit::msn }
    drawtext -r @muymsnp $rgb(31,51,107) Tahoma 11 27 10 Mesaj Uyarıcısı
    if (!%mpn::msn) drawpic @muymsnp 10 35 $shortfn($scriptdirmesaj.ico)
    else { drawpic @muymsnp 13 35 $shortfn(%mpn::msn) | did -ra muy_msn 6 %mpn::msn }
    drawtext -r @muymsnp $rgb(31,51,107) Tahoma 11 50 50 Yeni mesajınız var...
    drawpic -s @muymsnp 10 77 16 16 $shortfn($scriptdiradd.ico)
    drawtext -r @muymsnp $rgb(131,131,131) Tahoma 11 30 79 Nick:
    drawtext -r @muymsnp $rgb(72,100,142) Tahoma 11 55 79 SeRDaR406
    drawpic -s @muymsnp 10 97 16 16 $shortfn($scriptdirtext.ico)
    drawtext -r @muymsnp $rgb(131,131,131) Tahoma 11 30 100 Mesaj:
    drawtext -r @muymsnp $rgb(72,100,142) Tahoma 11 63 100 Who are u?
  }
}
alias -l muy_msn_prev {
  if (!$window(@muymsnp)) { 
    window -hpdok[0] +tL @muymsnp $calc($dialog(muy_msn).x + 250) $dialog(muy_msn).y 200 150
    window -a @muymsnp | drawrect -rf @muymsnp $rgb(100,100,100) 1 0 0 210 200 
    muy_msn_tools    
    .timermuymsnc 0 0 muy_msn_algıla
  }
}
alias -l muy:msn:titicon {
  var %mmsn:tit = $sfile($mircdir,Ikon dosyası seç)
  if (($len(%mmsn:tit) > 0) && ($gettok(%mmsn:tit,-1,46) == ico)) { 
    set %mtit::msn %mmsn:tit | muy_msn_tools 
  }
}
alias -l muy:msn:pnicon {
  var %mmsn:pn = $sfile($mircdir,Ikon dosyası seç)
  if (($len(%mmsn:pn) > 0) && ($gettok(%mmsn:pn,-1,46) == ico)) {
    set %mpn::msn %mmsn:pn | muy_msn_tools
  }
}
alias -l muy:msn:wav {
  var %mmsn:wav = $sfile($mircdir,Dosya seç[*.wav])
  if (($len(%mmsn:wav) > 0) && ($gettok(%mmsn:wav,-1,46) == wav)) { set %muy:msn:wav %mmsn:wav | did -ra muy_msn 10 %mmsn:wav | did -e muy_msn 12 }
}
on *:dialog:muystyle:sclick:*: {
  if ($did == 2) { set %muy:style normal | muydlg muyd | dialog -x $dname $dname | if ($dialog(muy_msn)) dialog -x muy_msn muy_msn }
  if ($did == 4) { set %muy:style msn | if (!$dialog(muy_msn)) dialog -m muy_msn muy_msn | dialog -x $dname $dname | if ($dialog(muyd)) dialog -x muyd muyd }
}
alias -l muy_msn_algıla {
  if (!$window(@muymsnp)) { 
    if ($dialog(muy_msn)) { did -ra muy_msn 17 Önizleme(Kapalı) | did -e muy_msn 17 } 
    .timermuymsnc off 
  }
  if (!$dialog(muy_msn)) { if ($window(@muymsnp)) window -c @muymsnp | .timermuymsnc off }
}
on *:dialog:muy_msn:sclick:*: {
  if ($did == 17) muy_msn_prev 
  if ($did == 4) muy:msn:titicon 
  if ($did == 7) muy:msn:pnicon 
  if ($did == 11) muy:msn:wav 
  if ($did == 14) set %muy:msn:pos left
  if ($did == 15) set %muy:msn:pos right
  if ($did == 18) set %muy:msn:stat on
  if ($did == 19) set %muy:msn:stat off
  if ($did == 16) { unset %mtit::msn %mpn::msn %muy:msn:wav %muy:msn:pos %muy:msn:stat | did -r $dname 3,6,10 | did -u $dname 14,15,18,19 | did -c $dname 14,18 | did -b $dname 12 | muy_msn_tools }
  if ($did == 17) { did -ra $dname 17 Önizleme(Açık) | did -b $dname 17 | muy_msn_prev  }
  if ($did == 12) if ($isfile($shortfn(%muy:msn:wav)) == $true) splay $shortfn(%muy:msn:wav) 
}
on *:dialog:muy_msn:init:*: {
  muy_msn_prev
  if (%muy:msn:wav != $null) { did -a $dname 10 %muy:msn:wav | did -e $dname 12 }
  if (!%muy:msn:pos) set %muy:msn:pos left
  if (!%muy:msn:stat) set %muy:msn:stat on
  if (%muy:msn:pos == left) did -c $dname 14 
  elseif (%muy:msn:pos == right) did -c $dname 15
  if (%muy:msn:stat == on) did -c $dname 18
  elseif (%muy:msn:stat == off) did -c $dname 19
}
alias -l muy_msn_up {
  if ($window(@muymsn)) {
    %muy:msny = $calc(%muy:msny - 13)    
    window @muymsn %muy:msnx %muy:msny
    if (%muy:msny == $calc($window(-1).h - 143)) { .timermsndowngo 1 4 .timermsndown 0 0 muy_msn_down | .timermsnup off  }
  }
}
alias -l muy_msn_down {
  if ($window(@muymsn)) { 
    %muy:msny = $calc(%muy:msny + 13)
    window @muymsn %muy:msnx %muy:msny 
    if (%muy:msny == $calc($window(-1).h + 143)) { .timermsndown off | window -c @muymsn }
  }
}
alias -l isfil return $isfile($shortfn($+($scriptdir,$1-)))
alias -l unload::addon {
  echo Eksik dosya $+(4",$1,") Bu dosyayı $+(4",$scriptdir,") adlı yere kopyalayınız.
  .unload -rs $shortfn($script)
}
alias -l check_files {
  if ($isfil(cbox.mrc) == $false) unload::addon cbox.mrc
  elseif ($isfil(info.ico) == $false) unload::addon info.ico
  elseif ($isfil(users.ico) == $false) unload::addon users.ico
  elseif ($isfil(xx.ico) == $false) unload::addon xx.ico
  elseif ($isfil(mesaj.ico) == $false) unload::addon mesaj.ico
  elseif ($isfil(hop2.ico) == $false) unload::addon hop2.ico
  elseif ($isfil(text.ico) == $false) unload::adonn text.ico
  elseif ($isfil(add.ico) == $false) unload::addon add.ico
  elseif ($isfil(msn.jpg) == $false) unload::adon msn.jpg
  else { .load -rs $shortfn($scriptdircbox.mrc) | echo -a 4Mesaj Uyarıcısı v0.2 BY SeRDaR406 | echo -a 7Addon yüklendi. | muy }
}
alias cdidk set %muy:msn:stat off 
alias -l muyar_msn {
  if (!%muy:style) set %muy:style msn
  if ($1 == -c) && (%muy:msn:stat == on) {
    if (!$window(@muymsn)) {
      set %muy:msnx $calc($window(-1).w - 190)
      set %muy:msny $calc($window(-1).h + 143)
      window -dohpB +dL @muymsn %muy:msnx %muy:msny 181 115
      window @muymsn %muy:msnx %muy:msny
      drawrect -r @muymsn $rgb(255,255,255) 1 163 6 13 13
      drawpic @muymsn 0 0 $shortfn($scriptdirmsn.jpg)
      drawpic -s @muymsn 5 4 16 16 $shortfn($scriptdirinfo.ico)
      drawtext -r @muymsn $rgb(31,51,107) Tahoma 11 27 5 Mesaj Uyarıcısı
      drawpic @muymsn 7 30 $shortfn($scriptdirhop2.ico)
      drawtext -r @muymsn $rgb(31,51,107) Tahoma 11 43 45 Kanalda size seslenen var..
      drawpic -s @muymsn 10 67 16 16 $shortfn($scriptdirxx.ico)
      drawtext -r @muymsn $rgb(131,131,131) Tahoma 11 30 70 Kanal:
      drawpic -s @muymsn 10 92 16 16 $shortfn($scriptdirmesaj.ico)
      drawtext -r @muymsn $rgb(131,131,131) Tahoma 11 30 95 Mesaj:
      if ($len(#) <= 21) drawtext -r @muymsn $rgb(72,100,142) Tahoma 11 60 70 #
      else { drawtext -rc @muymsn $rgb(72,100,142) Tahoma 11 60 70 110 $height(#,Tahoma,11) # | drawtext -r @muymsn $rgb(72,100,142) Tahoma 11 165 70 ... }
      if ($len($2-) <= 19) drawtext -r @muymsn $rgb(72,100,142) Tahoma 11 64 95 $2-
      else { drawtext -rc @muymsn $rgb(72,100,142) Tahoma 11 64 95 97 $height($2-,Tahoma,11) $2- | drawtext -r @muymsn $rgb(72,100,142) Tahoma 11 163 95 ... }
      cbox @muymsn 145 6 | cdid -c 1 | cdid -k 1 cdidk
      .timermsnup 0 0 muy_msn_up  
    }
  }
  elseif ($1 == -q) {
    if ((%muy:msn:stat == on) && (!$window(@muymsn))) {
      if (%muy:msn:pos == left) set %muy:msnx $calc($window(-1).w - 190)
      if (%muy:msn:pos == right) set %muy:msnx $calc($window(-1).x + 10)
      set %muy:msny $calc($window(-1).h + 143)
      window -dohpB +dL @muymsn %muy:msnx %muy:msny 181 115
      window @muymsn %muy:msnx %muy:msny
      drawrect -r @muymsn $rgb(255,255,255) 1 163 6 13 13
      drawpic @muymsn 0 0 $shortfn($scriptdirmsn.jpg)
      if (!%mtit::msn) drawpic -s @muymsn 5 4 16 16 $shortfn($scriptdirinfo.ico)
      else drawpic -s @muymsn 5 4 16 16 $shortfn(%mtit::msn)
      drawtext -r @muymsn $rgb(31,51,107) Tahoma 11 27 5 Mesaj Uyarıcısı
      if (!%mpn::msn) drawpic @muymsn 10 30 $shortfn($scriptdirmesaj.ico)
      else drawpic @muymsn 10 30 $shortfn(%mpn::msn)
      drawtext -r @muymsn $rgb(31,51,107) Tahoma 11 50 45 Yeni mesajınız var...
      drawpic -s @muymsn 10 67 16 16 $shortfn($scriptdiradd.ico)
      drawtext -r @muymsn $rgb(131,131,131) Tahoma 11 30 70 Nick:
      drawpic -s @muymsn 10 92 16 16 $shortfn($scriptdirtext.ico)
      drawtext -r @muymsn $rgb(131,131,131) Tahoma 11 30 95 Mesaj:
      if ($len($nick) <= 21) drawtext -r @muymsn $rgb(72,100,142) Tahoma 11 55 70 $nick
      else { drawtext -rc @muymsn $rgb(72,100,142) Tahoma 11 55 70 110 $height($nick,Tahoma,11) $nick | drawtext -r @muymsn $rgb(72,100,142) Tahoma 11 165 70 ... }
      if ($len($2-) <= 19) drawtext -r @muymsn $rgb(72,100,142) Tahoma 11 64 95 $2-
      else { drawtext -rc @muymsn $rgb(72,100,142) Tahoma 11 64 95 97 $height($2-,Tahoma,11) $2- | drawtext -r @muymsn $rgb(72,100,142) Tahoma 11 163 95 ... }
      .timermsnup 0 0 muy_msn_up   
      cbox @muymsn 145 6 | cdid -c 1 | cdid -k 1 cdidk
      if ((%muy:msn:wav != $null) && ($isfile($shortfn(%muy:msn:wav)) == $true)) splay $shortfn(%muy:msn:wav)
    }
  }
}
menu @muymsn {
  uclick: {
    if ($inrect($mouse.x,$mouse.y,163,6,13,13)) { window -c @muymsn | .timermsndown off | .timermsndowngo off }
  }
}
on *:TEXT:*:*: {
  if (($chan != $null) && ($active != $chan) && ($me isin $1-)) muyar_msn -c $1-
  if (($appactive == $false) || ($window(-2).state == minimized)) { 
    if (($nick != $me) && (!$chan)) { 
      if (%muy:style == normal) muyar $1-
      if (%muy:style == msn) muyar_msn -q $1-
    } 
  }
}
menu @muyar {
  uclick: {
    if ($inrect($mouse.x,$mouse.y,155,5,12,12)) { window -c @muyar | .timerwinup off | .timernmsg off | .timerwindwn off }
    if ($inrect($mouse.x,$mouse.y,128,21,$width(Ayarlar,Tahoma,10,1),$height(Ayarlar,Tahoma,10))) { muydlg muyd }
  }
}
menu menubar,status,query {
  Mesaj Uyarıcısı
  .Ayarlar : muy
  .-
  .Addonu kaldır : .unload -rs $shortfn($script)
}
on *:load: check_files
on *:unload: {
  echo -a Addon Kaldırıldı!
  unset %mnx %mny %mnx::win %mny::win %mlen %nmsgl %nmsgclr %::pnicon %::titicon %muytit %muynick %muymsg %muybgclr %mtema %b::clr %btxt::clr %wy %win::pos %wx %rgbp %::sndf %icon::tmode %icon::pmode %muy::state %tm::id %mtit::msn %mpn::msn %muy:msn:wav %muy:msn:pos %muy:msn:stat %muy:msnx %muy:msny %muy:style
}
;KOD SONU
;Bana tahammül ettiğiniz için tşk (:
